The evolute of the cycloid (Problem 3 -1)

γ[t_]:={t-Sin[t],1-Cos[t]};
cyc=ParametricPlot[γ[t],{t,0,2Pi}]

a=1;
ParametricPlot[γ[t],{t,0-a,2Pi+a}]

dγ[t_]:=Evaluate[D[γ[t],t]//Simplify//TrigExpand];
ds[t_]:=Evaluate[(Sqrt[dγ[2s].dγ[2s]]//Simplify//PowerExpand)/.s->t/2];
tang[t_]:=Evaluate[dγ[t]/ds[t]//Simplify];
norm[t_]:=Evaluate[{-tang[t][[2]],tang[t][[1]]}];
ddγ[t_]:=D[dγ[t],t]//Simplify;
κ[t_]:=Evaluate[Det[{dγ[t],ddγ[t]}]/ds[t]^3//Simplify]

σ[t_]:=Evaluate[γ[t]+1/κ[t] norm[t]//Simplify]

σ[t]

cycEvol=ParametricPlot[{γ[t],σ[t]},{t,0,2Pi}]

ParametricPlot[{γ[t],σ[t]},{t,0,4Pi}]

Normal line congruence of the cycloid

u1=5; u2=1;
cong=Graphics[Table[Line[{γ[t]-u1 norm[t],γ[t]+u2 norm[t]}],{t,0,2Pi,Pi/12}]];

Show[cong,cycEvol]

Parallel Curves of the cycloid

parallel=Table[ParametricPlot[γ[t]+ u norm[t],{t,0,2Pi},PlotRange->{{-0.2,2Pi+0.2},{-5,2.1}}],
	{u,0,-5,-1/5}];
parallel1=Table[Show[parallel[[j]],cyc],{j,1,Length[parallel]}];
parallel2=Table[Show[parallel[[j]],cycEvol],{j,1,Length[parallel]}];
paralleldist=Table[
Graphics[Table[Line[{γ[t],γ[t]+ u norm[t]}],{t,0,2Pi,Pi/12}]],
{u,0,-5,-1/5}];
parallel3=Table[Show[{parallel[[j]],paralleldist[[j]],cyc}],
	{j,1,Length[parallel]}];

parallels=Show[parallel,PlotRange->All];

ListAnimate[parallel3]

Show[parallels,cycEvol]

The tractrix

bound=3;

ϕ[t_]:= {Sech[t],t-Tanh[t]};
trac=ParametricPlot[ϕ[t],{t,0,bound}]

dϕ[t_]:=Evaluate[D[ϕ[t],t]//Simplify];
du[t_]:=Evaluate[Sqrt[dϕ[t].dϕ[t]]//Simplify//PowerExpand];
ddϕ[t_]:=Evaluate[D[dϕ[t],t]//Simplify];
k[t_]:=Evaluate[ Det[{dϕ[t],ddϕ[t]}]/du[t]^3//Simplify]

tangents=Table[
Graphics[{Line[{ϕ[t],{0,t}}],
	{PointSize[0.02],Point[ϕ[t]],Point[{0,t}]}}],{t,0,bound,bound/21}];
tracTan=Show[trac,tangents];
tracTan1=Table[
Show[trac,tangents[[j]],
	PlotRange->{{-0.2,1.2},{-0.2,ϕ[bound][[2]]+0.2}}],{j,1,Length[tangents]}];

Show[tracTan]

ListAnimate[tracTan1]